Formules Excel essentielles
Les fonctions indispensables, leur syntaxe française exacte, un exemple de la vie courante pour chacune, les valeurs d'erreur et leur remède.
Lire cette fiche
Une formule commence par =. Les arguments se séparent par un point-virgule ; la virgule est le séparateur décimal ; un texte s'écrit entre guillemets. Un argument [entre crochets] est facultatif. Les noms de fonction se saisissent en majuscules ou en minuscules.
Sauf mention contraire, les exemples portent sur deux fichiers d'exercices.
- Dépenses : feuille « Dépenses » de depenses.xlsx, lignes 2 à 61 : A Date · B Libellé · C Catégorie · D Magasin · E Moyen de paiement · F Montant.
- Adhérents : feuille « Adhérents » de adherents.xlsx, lignes 2 à 41 : A N° · B Nom · C Prénom · D Ville · E Date d'adhésion · F Adhésion · G Cotisation · H Date limite · I Date de paiement (vide = non payée) · J Statut. Date de référence en M1 : 30/11/2026.
Opérateurs · leçon 28
+ - * / | Additionner, soustraire, multiplier, diviser |
% | Pourcentage : 20% vaut 0,2 |
( ) | Calculé en premier : =5+2*3 → 11 ; =(5+2)*3 → 21 |
& | Coller deux textes (Adhérents) : =C2&" "&B2 → Fatima Garnier |
= <> | Égal à, différent de |
> < | Supérieur à, inférieur à |
>= <= | Supérieur ou égal, inférieur ou égal |
Priorité : %, puis * et /, puis + et -, puis &, puis les comparaisons.
Calculs de tous les jours · leçon 28
Exemple : un pull à 49,90 € en B2, une remise de 20 % en C2, une quantité ou un nombre de personnes (3) en D2.
| Je cherche | Formule | Résultat |
|---|---|---|
| Total d'une ligne = quantité × prix | =D2*B2 | 149,70 |
| Montant de la remise = prix × remise | =ARRONDI(B2*C2;2) | 9,98 |
| Prix après remise = prix × (1 − remise) | =ARRONDI(B2*(1-C2);2) | 39,92 |
| Partage d'une dépense = total / nombre de personnes | =ARRONDI(B2/D2;2) | 16,63 |
Un pourcentage se saisit 20% ou 0,2 : c'est le même nombre. Part d'un total : diviser la partie par le total, puis appliquer le format pourcentage. Alimentation, 868,51 sur 3 739,41 de dépenses : 23,2 %.
Références · leçon 30
| Écriture | Nom | À la recopie |
|---|---|---|
B2 | relative | se décale : B3, B4… |
$B$1 | absolue | ne bouge jamais |
B$1 | mixte | la ligne 1 reste, la colonne suit |
$B1 | mixte | la colonne B reste, la ligne suit |
B2:B10 | plage | de B2 jusqu'à B10 |
$B$2:$B$10 | plage bloquée | ne bouge jamais |
Tarifs!A2 | autre feuille | nom de la feuille, puis ! |
'Budget 2026'!A2 | autre feuille | apostrophes si le nom contient un espace |
F4, pendant la saisie, pose les $ sur la référence que l'on vient de désigner. À bloquer avant de recopier : un taux de remise, une date de référence, un total, les plages de SOMME.SI.ENS et de RECHERCHEX. Pour désigner une cellule d'une autre feuille, le plus sûr est de cliquer dessus : Excel écrit la référence.
Totaliser et compter · leçon 29
| Syntaxe | Exemple | Résultat |
|---|---|---|
SOMME(nombre1;[nombre2];...) | =SOMME(F2:F61)total des dépenses | 3 739,41 |
MOYENNE(nombre1;[nombre2];...) | =MOYENNE(F2:F61)dépense moyenne | 62,32 |
MIN(nombre1;[nombre2];...) | =MIN(F2:F61)plus petite dépense | 1,70 |
MAX(nombre1;[nombre2];...) | =MAX(F2:F61)plus grosse dépense | 720,00 |
NB(valeur1;[valeur2];...)compte les nombres et les dates | =NB(I2:I41)cotisations payées (Adhérents) | 26 |
NBVAL(valeur1;[valeur2];...)compte les cellules non vides | =NBVAL(A2:A61)nombre de dépenses | 60 |
Bouton Somme automatique (Σ) : onglets Accueil et Formules. Sans formule : sélectionner les cellules et lire la barre d'état, en bas de la fenêtre.
Ligne Total d'un tableau (leçon 31) : Excel y écrit une formule SOUS.TOTAL, qui ne compte que les lignes affichées par le filtre. SOMME, elle, additionne aussi les lignes masquées.
Conditions · leçon 32
| Syntaxe | Rôle |
|---|---|
SI(test_logique;valeur_si_vrai;[valeur_si_faux]) | Une réponse si le test est vrai, une autre sinon |
ET(logique1;[logique2];...) | Vrai si toutes les conditions sont vraies |
OU(logique1;[logique2];...) | Vrai si au moins une est vraie |
NON(logique) | Inverse vrai et faux |
SIERREUR(valeur;valeur_si_erreur) | Remplace une valeur d'erreur par un message |
| Besoin | Formule |
|---|---|
| Signaler une grosse dépense (Dépenses) | =SI(F2>100;"Grosse dépense";"") |
| Statut d'une cotisation, date de référence en M1 (Adhérents) | =SI(I2<>"";"Payée";SI(H2<$M$1;"En retard";"En attente")) |
| Non payée et date limite dépassée (Adhérents) | =SI(ET(I2="";H2<$M$1);"Oui";"Non") |
| Budget dépassé ? Dépensé en C2, budget en B2 (leçon 44) | =SI(C2>B2;"Dépassement";"Dans le budget") |
| Division protégée : total en B2, nombre de personnes en C2 | =SIERREUR(B2/C2;"Nombre manquant") |
| Cellule de contrôle (leçon 38) | =SI(ARRONDI(M4-M3;2)=0;"OK";"ERREUR") |
"" : cellule vide. Excel s'arrête à la première condition vraie : commencer par le cas le plus certain. Résultats sur les 40 adhérents au 30/11/2026 : 26 cotisations payées, 8 en retard, 6 en attente. Sur les 60 dépenses : 7 dépassent 100 €.
Totaliser selon des critères · leçon 33
| Syntaxe | À retenir |
|---|---|
SOMME.SI.ENS(somme_plage;plage_critères1;critères1;[plage_critères2;critères2];...) | Plage à additionner en premier |
NB.SI.ENS(plage_critères1;critères1;[plage_critères2;critères2];...) | Compte les lignes |
SOMME.SI(plage;critère;[somme_plage]) | Un seul critère ; plage à additionner en dernier |
NB.SI(plage;critères) | Un seul critère |
| Question (Dépenses) | Formule | Résultat |
|---|---|---|
| Total de la catégorie Alimentation | =SOMME.SI.ENS(F2:F61;C2:C61;"Alimentation") | 868,51 |
| Nombre de dépenses d'alimentation | =NB.SI.ENS(C2:C61;"Alimentation") | 22 |
| Transport en novembre 2026 (H1 = 01/11/2026, H2 = 30/11/2026) | =SOMME.SI.ENS(F2:F61;C2:C61;"Transport";A2:A61;">="&H1;A2:A61;"<="&H2) | 377,53 |
| Dépenses payées par carte | =NB.SI(E2:E61;"Carte") | 32 |
| Dépenses de plus de 100 € | =NB.SI(F2:F61;">100") | 7 |
| Cotisations non payées (Adhérents) | =NB.SI.ENS(I2:I41;"") | 14 |
| Synthèse recopiable, catégorie en H2 | =SOMME.SI.ENS($F$2:$F$61;$C$2:$C$61;H2) |
| Critère | Lignes retenues |
|---|---|
H2 | égales au contenu de H2 |
100 · "En retard" | égales à ce nombre, à ce texte |
">100" · "<>Carte" | supérieures à 100 · différentes de Carte |
">="&H1 | supérieures ou égales au contenu de H1 (dates) |
"" | vides |
"Abonnement*" | qui commencent par Abonnement (* : n'importe quelle suite de caractères) |
Toutes les plages ont la même hauteur. Résultat 0 inattendu : guillemets oubliés, espace en trop dans le critère, ou montants saisis en texte.
Rechercher · leçon 34
RECHERCHEX(valeur_cherchée;tableau_recherche;tableau_renvoyé;[si_non_trouvé];[mode_correspondance];[mode_recherche])
| Je veux | Formule | Résultat |
|---|---|---|
| Le tarif du type d'adhésion de F2 (Adhérents) | =RECHERCHEX(F2;Tarifs!$A$2:$A$5;Tarifs!$B$2:$B$5) | 40,00 pour Famille |
| Sa description, avec un message si le type d'adhésion est inconnu | =RECHERCHEX(F2;Tarifs!$A$2:$A$5;Tarifs!$C$2:$C$5;"Adhésion inconnue") | Moins de 25 ans pour Jeune |
| Le budget mensuel de la catégorie de C2 (Dépenses) | =RECHERCHEX(C2;Catégories!$A$2:$A$9;Catégories!$B$2:$B$9) | 480,00 pour Alimentation |
RECHERCHEX cherche la valeur exacte. Elle n'existe pas dans Excel 2016 ni 2019.
Dans les anciens classeurs : RECHERCHEV(valeur_cherchée;table_matrice;no_index_col;[valeur_proche]). Exemple : =RECHERCHEV(F2;Tarifs!$A$2:$B$5;2;FAUX). La valeur est cherchée dans la première colonne de la plage ; 2 = deuxième colonne ; toujours écrire FAUX pour une recherche exacte.
Dates et délais · leçons 27 et 32
Une date est un nombre de jours : on peut soustraire, ajouter, comparer. Exemples sur Adhérents.
| Besoin | Formule |
|---|---|
| Trente jours après une date | =E2+30 |
| Jours entre deux dates : paiement moins date limite | =I2-H2 → 3 en ligne 2 |
| Jours de retard à la date de référence (M1), statut en J2 | =SI(J2="En retard";$M$1-H2;"") → 46 en ligne 22 |
| Dernier jour du mois d'une date | =FIN.MOIS(E2;0) |
| Dernier jour du mois suivant | =FIN.MOIS(E2;1) |
| Même jour, un mois plus tard | =MOIS.DECALER(E2;1) |
| Même jour, un an plus tard | =MOIS.DECALER(E2;12) |
| Date du jour (change chaque jour) | =AUJOURDHUI() |
Syntaxes : FIN.MOIS(date_départ;mois) · MOIS.DECALER(date_début;mois) · AUJOURDHUI(). Pour un état daté (cotisations en retard, dates limites), saisir la date de référence dans une cellule plutôt que d'utiliser AUJOURDHUI : le résultat ne change pas d'un jour à l'autre. Un résultat affiché comme une date au lieu d'un nombre de jours : changer le format de nombre de la cellule.
Arrondir · leçon 38
ARRONDI(nombre;no_chiffres) — 2 = au centime, 0 = à l'euro.
| Part de chacun au centime : 49,90 € à trois | =ARRONDI(49,9/3;2) → 16,63 (au lieu de 16,6333…) |
| Écart entre deux totaux | =ARRONDI(M4-M3;2) → 0 si les totaux concordent |
Un format à deux décimales change l'affichage, pas la valeur : seul ARRONDI change le nombre calculé. Variantes : ARRONDI.SUP (vers le haut), ARRONDI.INF (vers le bas).
Nettoyer et comparer deux listes · leçons 37 et 45
| Problème | Remède |
|---|---|
| Espaces parasites dans un nom | =SUPPRESPACE(A2) — syntaxe SUPPRESPACE(texte) |
| Nombre stocké en texte | =CNUM(F2) — syntaxe CNUM(texte) |
Point décimal (62.50) | Sélectionner la colonne, Ctrl + H, remplacer le point par une virgule. Ou, dans une colonne voisine : =CNUM(SUBSTITUE(F2;".";",")) |
| Remplacer un morceau de texte | SUBSTITUE(texte;ancien_texte;nouveau_texte;[no_position]) |
| Extraire des caractères | GAUCHE(texte;[no_car]) · DROITE(texte;[no_car]) · STXT(texte;no_départ;no_car)=GAUCHE(C2;1) → F, l'initiale de Fatima (Adhérents) |
| Nombre mis en forme dans un texte | =TEXTE(F2;"# ##0,00 €") → 1,70 € (Dépenses) — syntaxe TEXTE(valeur;format_texte) |
| Un inscrit de la feuille Inscriptions a-t-il payé ? Son courriel est en C2 (fete-de-quartier.xlsx) | =NB.SI(Paiements!$B$2:$B$27;C2)0 = aucun paiement · 1 = un paiement reçu |
Contrôle après l'ouverture d'un fichier CSV : alignement des montants à droite, nombre de lignes (NB), total (SOMME). Fichier inscriptions-fete.csv : total de 1 037,50 avant correction des trois montants à point, 1 200,00 après.
Valeurs d'erreur et remèdes · leçon 38
| Affichage | Cause | Remède |
|---|---|---|
##### | Colonne trop étroite. Ce n'est pas une erreur. | Double-clic sur le bord droit de la lettre de colonne. |
#DIV/0! | Division par zéro ou par une cellule vide. | Compléter la donnée ; sinon SIERREUR(calcul;"message"). |
#N/A | RECHERCHEX ou RECHERCHEV ne trouve pas la valeur. | Faute de frappe, espace en trop (SUPPRESPACE), nombre stocké en texte. Prévoir l'argument « si non trouvé ». |
#NOM? | Nom de fonction mal orthographié, ou texte sans guillemets. | Corriger le nom, ajouter les guillemets. Ne jamais le masquer avec SIERREUR. |
#REF! | La formule pointe sur une cellule supprimée, ou sortie de la feuille à la recopie. | Ctrl + Z tout de suite ; sinon réécrire la référence, avec des $ si elle doit rester fixe. |
#VALEUR! | Calcul sur du texte ; plages de hauteurs différentes dans SOMME.SI.ENS. | Chercher la cellule alignée à gauche ; égaliser les plages. |
#NOMBRE! | Nombre impossible ou résultat trop grand. | Vérifier les données utilisées. |
#NUL! | Un espace à la place des deux-points : =SOMME(A1 A5). | Écrire A1:A5. |
| Sans message d'erreur | À vérifier |
|---|---|
| Excel refuse la formule | Une virgule au lieu d'un point-virgule ; une parenthèse non refermée ; un guillemet manquant. |
| La formule s'affiche telle quelle | Le signe = manque au début, ou la cellule est au format Texte. |
| Total trop faible | Des montants en texte, ignorés par SOMME : les compter avec NB. |
| Juste en ligne 2, faux plus bas | Une référence n'a pas été bloquée par des $ avant la recopie. |
| Un 0 à la place d'un total par critère | Guillemets oubliés, espace en trop, montants en texte. |
| Un écart de quelques centimes | ARRONDI ligne par ligne. |
Pour comprendre une formule : cliquer sur la cellule et lire la barre de formule ; F2 colore chaque référence et la cellule correspondante.
Les gestes qui vont avec
| Modifier la formule de la cellule | F2 |
| Poser les $ pendant la saisie | F4 |
| Valider · renoncer | Entrée · Échap |
| Désigner une cellule dans une formule | cliquer dessus au lieu de saisir sa référence |
| Recopier jusqu'en bas | double-clic sur la poignée de recopie |
| Recopier la cellule du dessus | Ctrl + D |
| Sélectionner jusqu'au bas de la colonne | Ctrl + Maj + ↓ |
| Créer un tableau | Ctrl + L ou Ctrl + T |
| Annuler | Ctrl + Z |
Tous les raccourcis : fiche Raccourcis clavier. Le vocabulaire : glossaire, rubrique Excel.
Bac à sable
Un mini-tableur libre pour essayer n'importe quelle formule de cette fiche. Rien n'est noté, rien n'est enregistré. Les colonnes E et F de la ligne 2 contiennent déjà une formule : cliquez dessus pour la lire, puis recopiez-la vers le bas.
Sources officielles
Microsoft : opérateurs et priorités · SOMME · références relatives et absolues · SI · SOMME.SI.ENS · RECHERCHEX · ARRONDI · FIN.MOIS · détecter les erreurs de formule. Plusieurs de ces pages affichent les arguments séparés par des virgules (défaut de traduction) : sur un ordinateur réglé en français, c'est toujours le point-virgule.